home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Magnum One
/
Magnum One (Mid-American Digital) (Disc Manufacturing).iso
/
d20
/
duchie.arc
/
DU291US3.EXE
/
pak
/
HUISARTS.SCR
< prev
next >
Wrap
Text File
|
1989-11-17
|
3KB
|
111 lines
;===================================================
; Terugbel script voor 2.91 en hoger
;
; (c) 1989 A.C.S.
;====================================================
;Zet een algemene time-out voor dit script
watchdog 500
;Zet een algemene foutafhandelings uitgang. Maakt het script
;een stuk makkelijker leesbaar
OnError Error
;Zet de modem gereed voor uitgaande post en bel
SetDtr On
ModemCommand SetupOut
;======================================================
; vul het VU telefoonnummer hier in
Show Bel nu ......xxxxx\
Dial xxxxx
;======================================================
;Als we hier zijn gekomen dan is de verbinding tot stand gekomen
Show Verbinding in orde\
;Handel nu de log in procedure af. We zetten de algemene foutafhandeling
;af zodat we bij een mislukte login een aantal nieuwe pogingen kunnen
;doen. Het aantal niewe pogingen wordt bijgehouden in twee tellers
Onerror OFF
setcounter 2 0
Label TryAgain
setCounter 1 0
repeat
Waitfor 10 ID:
IfFlag IsOk
Emit |
IncCounter 1 1
TestCounterEQ 1 3
untilFlag
Goto Error
Label IsOk
;==========================================
; zet hier de gebruikersnaam
Emit xxxxx|
;==========================================
Waitfor 10 Password:
IfNotFlag Error
;===========================================
; zet hier het wachtwoord
Emit xxxxx|
;===========================================
Waitfor 10 accepted
IfFlag IsOk1
IncCounter 2 1
TestCounterEQ 2 3
IfNotFlag TryAgain
GoTo Error
Label IsOk1
;als we tot hier zijn gekomen, dan is de login gelukt. We wachten
;tot we terug worden gebeld.
OnError Error
Show Log in gelukt. Wacht nu op het terugbellen..
Wait 5
SetDtr Off
ClearInBuf
ClearOutBuf
SetDtr on
ModemCommand SetUpIn
;We wachten maximaal 75 seconden op het terugbellen
WaitforCall 75
;Als we hier zijn, dan zijn we teruggebeld.
Show \
OnError Off
;****************************************************
; LET OP ! de volgende regel te vervangen door de
; daaropvolgende twee regels bij NIET MNP
; modems, waarbij de mailconnectie niet goed
; tot stand komt. Omdat de VU een MNP modem heeft
; en deze de eerste 30 seconden 'rommel'
; zendt.
;******************************************************
Waitfor 30 Access_Enabled
; Show 30 seconden wachttijd gestart\
; Wait 30
;Het lijkt in orde, terug naar dutchie
Show Toegang verkregen. Start nu Mail sessie\
clearoutbuf
clearinbuf
Exit
Label Error
SetDtr Off
Show Een fout, script afgebroken\
Abort 255